Gemaakt voor gebruik in MSI project waarbij advertised snelkoppelingen naar applicaties op de netwerkschijf gemaakt moeten worden. Hierbij staat het merendeel van de applicatie op een netwerkschijf met een paar onderdelen, waaronder de snelkoppeling(en), lokaal.

'StartAppWithParams.vbs
'Template VBScript voor starten van een applicatie (van een netwerkschijf).
'Deze versie is bedoeld om aangeroepen te worden met 1 tot 3 parameters.
'20090916, v1.
 
'Voorbeelden voor gebruik:
'StartAppWithParams.vbs "C:\Program Files\Internet Explorer\iexplore.exe" "C:\temp" "http://www.microsoft.com"
'StartAppWithParams.vbs "C:\WINDOWS\notepad.exe" "" "c:\WINDOWS\setuperr.log"
'StartAppWithParams.vbs "C:\WINDOWS\system32\cmd.exe"
 
On Error Resume Next
 
Const intWindowStyle = 1
 
Set objParam = WScript.Arguments
 
'Als er 0 of meer dan 3 parameters zijn opgegeven,
'geef dan een (fout)melding.
If objParam.Count = 0 OR objParam.Count > 3 Then
 
	WScript.Echo "Wrong number of parameters."
 
	WScript.Quit
 
End If
 
strExeFile = objParam(0)
 
'Als de tweede parameter, de workingdir, niet is opgegeven, of een lege string is,
'neem dan aan dat deze gelijkgesteld moet worden aan de applicatie directory.
If objParam.Count = 1 OR objParam(1) = "" Then
 
 
	If InStr(objParam(0), "\") > 0 Then
 
		'Neem het linkergedeelte tot de laatste "\" als workingdirectory.
		strWorkingDir = Left(objParam(0), InStrRev(objParam(0), "\") - 1)
 
	Else
 
		strWorkingDir = ""
 
	End If
 
Else
 
	strWorkingDir = objParam(1)
 
End If
 
'Als de derde parameter, de parameters voor de te starten applicatie,
'leeg is
If objParam.Count < 3 Then
 
	strParameters = ""
 
Else
 
	strParameters = objParam(2)
 
End If
 
Set objShell = CreateObject("WScript.Shell")
 
If strWorkingDir <> "" Then
 
	objShell.CurrentDirectory = strWorkingDir
 
End If
 
objShell.Run chr(34) & strExeFile & chr(34) & " " & strParameters
 
Set objShell = Nothing