Notes

Maakt in de opgegeven directory per datum van de aanwezige bestanden in het yyyymmdd formaat subdirectories aan en verplaatst de bestanden in de directory op datum naar de subdirectories.
Bedoeld voor een directory waar veel van dezelfde bestanden in terechtkomen als uitvoer uit een programma.

'SortFilesInSubFolders.vbs
'Voor het archiveren van bestanden in een directory in subdirectories op datum.
 
On Error Resume Next
 
Set objFso = CreateObject("Scripting.FileSystemObject")
 
'Voor het formatteren van een datum naar yyyymmdd.
Function FormatDate(strDate)
 
	strDay = datepart("d", strDate)
 
	If len(strDay) = 1 Then
		strDay = "0" & strDay
	End If
 
	strMonth = datepart("m", strDate)
 
	If len(strMonth) = 1 Then
		strMonth = "0" & strMonth
	End If
 
	strYear = datepart("yyyy", strDate)
 
	FormatDate = strYear & strMonth & strDay
 
End Function
 
'Voor het sorteren van bestanden op Date Modified.
'Alleen de bestanden van de huidige datum blijven staan.
'Gaat uit van het niet bestaan van bestanden met een datum in de toekomst.
Function SortFilesByDateModifiedInSubFolders(strWorkFolder)
 
	Set fldrWorkFolder = objFso.GetFolder(strWorkFolder)
 
	For Each file in fldrWorkFolder.Files
 
		Set fileInWorkFolder = objFso.GetFile(strWorkFolder & "\" & file.name)
 
		FileDate = FormatDate(fileInWorkFolder.DateLastModified)
 
		If  FileDate <> myDate Then
 
			If Not objFso.FolderExists(strWorkFolder & "\" & FileDate) Then
 
				objFso.CreateFolder(strWorkFolder & "\" & FileDate)
 
			End If
 
			objFso.MoveFile strWorkFolder & "\" & file.name, strWorkFolder & "\" & FileDate & "\"
 
		End If
 
		Set fileInWorkFolder = Nothing
 
	Next
 
	Set WorkFolder = Nothing
 
End Function
 
 
myDate = FormatDate(date)
 
SortFilesByDateModifiedInSubFolders("C:\test\test")
 
Set objFso = Nothing